Macaulay2 » Documentation
Packages » NormalToricVarieties :: toricProjectiveSpace(ZZ)
next | previous | forward | backward | up | index | toc

toricProjectiveSpace(ZZ) -- make a projective space as a normal toric variety

Description

Projective $d$-space is a smooth complete normal toric variety. The rays are generated by the standard basis $e_1, e_2, \dots,e_d$ of $\ZZ^d$ together with vector $-e_1-e_2-\dots-e_d$. The maximal cones in the fan correspond to the $d$-element subsets of $\{ 0,1, \dots,d\}$.

The examples illustrate the projective line and projective $3$-space.

i1 : PP1 = toricProjectiveSpace 1;
 
i2 : rays PP1

o2 = {{-1}, {1}}

o2 : List
 
i3 : max PP1

o3 = {{0}, {1}}

o3 : List
 
i4 : dim PP1

o4 = 1
 
i5 : ring PP1

o5 = QQ[x ..x ]
         0   1

o5 : PolynomialRing
 
i6 : ideal PP1

o6 = ideal (x , x )
             1   0

o6 : Ideal of QQ[x ..x ]
                  0   1
 
i7 : assert (isWellDefined PP1 and isSmooth PP1 and isComplete PP1)
 
i8 : PP3 = toricProjectiveSpace (3, CoefficientRing => ZZ/32003, Variable => y);
 
i9 : rays PP3

o9 = {{-1, -1, -1}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}

o9 : List
 
i10 : max PP3

o10 = {{0, 1, 2}, {0, 1, 3}, {0, 2, 3}, {1, 2, 3}}

o10 : List
 
i11 : dim PP3

o11 = 3
 
i12 : ring PP3

        ZZ
o12 = -----[y ..y ]
      32003  0   3

o12 : PolynomialRing
 
i13 : ideal PP3

o13 = ideal (y , y , y , y )
              3   2   1   0

                 ZZ
o13 : Ideal of -----[y ..y ]
               32003  0   3
 
i14 : assert (isWellDefined PP3 and isSmooth PP3 and isComplete PP3)

See also

Ways to use this method:

The source of this document is in NormalToricVarieties/ToricVarietiesDocumentation.m2:700:0.