GF -- make a finite field

Synopsis

• Usage:

  GF(p,n)

  GF(q)

• Inputs:
  • p, a prime number
  • n
  • Variable => a symbol, default value null, the name to use for the generator of the field. If null, then a is used.
  • SizeLimit => an integer, default value 10000, the limit on the size of a Galois field whose elements will be represented internally as powers of the primitive element
• Outputs:
  • a Galois field, a finite field with q = p^n elements

If the single argument form GF(q) is given, q should be a prime power q = p^n

i1 : A = GF(3,2,Variable=>b);

i2 : ambient A

        ZZ
        --[b]
         3
o2 = ----------
      2
     b  - b - 1

o2 : QuotientRing

i3 : b^8

o3 = 1

o3 : A

i4 : b^4

o4 = -1

o4 : A

i5 : K = GF 8

o5 = K

o5 : GaloisField

i6 : a^3+a

o6 = 1

o6 : K

Synopsis

• Usage:

  GF R

• Inputs:
  • R, a ring, A quotient of a polynomial ring over ZZ/p in one variable, modulo an irreducible polynomial
  • PrimitiveElement => ..., default value FindOne, either an element of R, or the symbol FindOne. An element is primitive if it generates the multiplicative group of non-zero elements of R
  • SizeLimit => an integer, default value 10000, the limit on the size of a Galois field whose elements will be represented internally as powers of the primitive element
• Outputs:
  • a Galois field, a finite field isomorphic to R

i7 : A = ZZ/5[a]/(a^3-a-2)

o7 = A

o7 : QuotientRing

i8 : B = GF A

o8 = B

o8 : GaloisField

i9 : C = ZZ/5[b]/(b^3+1+3*b^2+b)

o9 = C

o9 : QuotientRing

i10 : D = GF C

o10 = D

o10 : GaloisField

i11 : map(B,D,{a^2})

                   2
o11 = map (B, D, {a })

o11 : RingMap B <-- D