Macaulay2 » Documentation
Packages » Varieties :: singularLocus(AffineVariety)
next | previous | forward | backward | up | index | toc

singularLocus(AffineVariety) -- the locus of singular points in a variety

Description

The singular locus of a variety is the set of singular points of some variety $X$. Geometrically it is the intersection of the points in the variety $X$ with the points at which the associated jacobian matrix does not have maximal rank. Algebraically, this corresponds to the variety defined the ideal obtained by taking the sum of the defining ideal of $X$ and the maximal minors of the Jacobian matrix. In the projective case, one should also saturate to make sure the ideal defines a reduced object.

i1 : R = QQ[x,y]/(x^3 - y^2);
 
i2 : X = Spec R

o2 = X

o2 : AffineVariety
 
i3 : S = singularLocus X

o3 = S

o3 : AffineVariety
 
i4 : codim S

o4 = 2
 
i5 : trim ideal ring S

                2
o5 = ideal (y, x )

o5 : Ideal of QQ[x..y]

In the projective case, there may be additional irrelevant components that we would like to saturate away:

i6 : Q = QQ[x,y]/(x^2*y);
 
i7 : Y = Proj(Q)

o7 = Y

o7 : ProjectiveVariety
 
i8 : S' = singularLocus Y

o8 = S'

o8 : ProjectiveVariety
 
i9 : I = ideal ring S'

o9 = ideal x

o9 : Ideal of QQ[x..y]
 
i10 : J = minors(1,jacobian ideal Q) + ideal Q

                    2   2
o10 = ideal (2x*y, x , x y)

o10 : Ideal of QQ[x..y]
 
i11 : primaryDecomposition J

                           2
o11 = {ideal x, ideal (y, x )}

o11 : List

As we see in the above, without saturating there is an irrelevant component arising from the ideal $(x^2 , y)$ that disappears upon saturating.

See also

Ways to use this method:

The source of this document is in Varieties/doc-varieties.m2:300:0.