Teaching the Geometry of Schemes

Gregory G. Smith and Bernd Sturmfels

This chapter presents a collection of graduate level problems in algebraic geometry illustrating the power of Macaulay 2 as an educational tool.

When teaching an advanced subject, like the language of schemes, we think it is important to provide plenty of concrete instances of the theory. Computer algebra systems, such as Macaulay 2, provide students with an invaluable tool for studying complicated examples. Furthermore, we believe that the explicit nature of a computational approach leads to a better understanding of the objects being examined. This chapter presents some problems which we feel illustrate this point of view.

Our examples are selected from the homework of an algebraic geometry class given at the University of California at Berkeley in the fall of 1999. This graduate course was taught by the second author with assistance from the first author. Our choice of problems, as the title suggests, follows the material in David Eisenbud and Joe Harris’ textbook The Geometry of Schemes [5].

1 Distinguished Open Sets

We begin with a simple example involving the Zariski topology of an affine scheme. This example also indicates some of the subtleties involved in working with arithmetic schemes.

Problem. Let S = ℤ[x, y, z] and X = Spec(S). If f = x and X_{f} is the corresponding basic open subset in X, then establish the following:

(1) If e_{1} = x + y + z, e_{2} = xy + xz + yz and e_{3} = xyz are the elementary symmetric functions then the set {X_{e_{i}}}_{1≤i≤3} is an open cover of X_{f}.

(2) If p_{1} = x + y + z, p_{2} = x^{2} + y^{2} + z^{2} and p_{3} = x^{3} + y^{3} + z^{3} are the power sum symmetric functions then {X_{p_{i}}}_{1≤i≤3} is not an open cover of X_{f}.

Solution. (1) To prove that {X_{e_{i}}}_{1≤i≤3} is an open cover of X_{f}, it suffices to show that e_{1}, e_{2} and e_{3} generate the unit ideal in S_{f}; see Lemma I-16 in Eisenbud and Harris [5]. This is equivalent to showing that x^{m} belongs to the S-ideal ⟨e_{1}, e_{2}, e_{3}⟩ for some m ∈ ℕ. In other words, the saturation (⟨e_{1}, e_{2}, e_{3}⟩ : x^{∞}) is the unit ideal if and only if {X_{e_{i}}}_{1≤i≤3} is an open cover of X_{f}. We verify this in Macaulay 2 as follows:

    i1 : S = ZZ[x, y, z];
    i2 : elementaryBasis = ideal(x+y+z, x*y+x*z+y*z, x*y*z);
    o2 : Ideal of S

    i3 : saturate(elementaryBasis, x)
    o3 = ideal 1
    o3 : Ideal of S

(2) Similarly, to show that {X_{p_{i}}}_{1≤i≤3} is not an open cover of X_{f}, we prove that (⟨p_{1}, p_{2}, p_{3}⟩ : x^{∞}) is not the unit ideal. Calculating this saturation, we find

    i4 : powerSumBasis = ideal(x+y+z, x^2+y^2+z^2, x^3+y^3+z^3);
    o4 : Ideal of S
    i5 : saturate(powerSumBasis, x)
                                2            2
    o5 = ideal (6, x + y + z, 2y  + 2y*z + 2z , 3y*z)
    o5 : Ideal of S
    i6 : clearAll

which is not the unit ideal. ⊓ ⊔

The fact that 6 is a generator of the ideal (⟨p_{1}, p_{2}, p_{3}⟩ : x^{∞}) indicates that {X_{p_{i}}}_{1≤i≤3} does not contain the points in X lying over the points ⟨2⟩ and ⟨3⟩ in Spec(ℤ). If we work over a base ring in which 6 is a unit, then {X_{p_{i}}}_{1≤i≤3} would, in fact, be an open cover of X_{f}.

2 Irreducibility

The study of complex semisimple Lie algebras gives rise to an important family of algebraic varieties called nilpotent orbits. The next problem examines the irreducibility of a particular nilpotent orbit.

Problem. Let X be the set of nilpotent complex 3 × 3 matrices. Show that X is an irreducible algebraic variety.

Solution. A 3 × 3 matrix M is nilpotent if and only if its minimal polynomial p(T) equals T^{k}, for some k ∈ ℕ. Since each irreducible factor of the characteristic polynomial of M is also a factor of p(T), it follows that the characteristic polynomial of M is T^{3}. We conclude that the coefficients of the characteristic polynomial of a generic 3 × 3 matrix define the algebraic variety X.

To prove that X is irreducible over ℂ, we construct a rational parameterization. First, observe that GL_{3}(ℂ) acts on X by conjugation. Jordan’s canonical form theorem implies that there are exactly three orbits; one for each of the following matrices:

N_{(1,1,1)} = [ \begin{matrix}0 & 0 & 0 \\ 0 & 0 & 0 \\ 0 & 0 & 0 \end{matrix} ] , N_{(2,1)} = [ \begin{matrix}0 & 1 & 0 \\ 0 & 0 & 0 \\ 0 & 0 & 0 \end{matrix} ] and N_{(3)} = [ \begin{matrix}0 & 1 & 0 \\ 0 & 0 & 1 \\ 0 & 0 & 0 \end{matrix} ] .

Each orbit is defined by a rational parameterization, so it suffices to show that the closure of the orbit containing N_{(3)} is the entire variety X. We demonstrate this as follows:

i7 : S = QQ[t, y_0 .. y_8, a..i, MonomialOrder => Eliminate 10];
i8 : N3 = (matrix {{0,1,0},{0,0,1},{0,0,0}}) ** S
o8 = | 0 1 0 |
     | 0 0 1 |
     | 0 0 0 |
             3       3
o8 : Matrix S  <--- S
i9 : G = genericMatrix(S, y_0, 3, 3)
o9 = | y_0 y_3 y_6 |
     | y_1 y_4 y_7 |
     | y_2 y_5 y_8 |
             3       3
o9 : Matrix S  <--- S

To determine the entries in G · N_{(3)} · G^{−1}, we use the classical adjoint to construct the matrix det(G) · G^{−1}.

i10 : classicalAdjoint = (G) -> (
           n := degree target G;
           m := degree source G;
           matrix table(n, n, (i, j) -> (-1)^(i+j) * det(
                     submatrix(G, {0..j-1, j+1..n-1},
                          {0..i-1, i+1..m-1}))));
i11 : num = G * N3 * classicalAdjoint(G);
              3       3
o11 : Matrix S  <--- S
i12 : D = det(G);
i13 : M = genericMatrix(S, a, 3, 3);
              3       3
o13 : Matrix S  <--- S

The entries in G · N_{(3)} · G^{−1} give a rational parameterization of the orbit generated by N_{(3)}. Using elimination theory — see section 3.3 in Cox, Little and O‘Shea [2] — we give an “implicit representation” of this variety.

i14 : elimIdeal = minors(1, (D*id_(S^3))*M - num) + ideal(1-D*t);
o14 : Ideal of S
i15 : closureOfOrbit = ideal selectInSubring(1, gens gb elimIdeal);
o15 : Ideal of S

Finally, we verify that this orbit closure equals X scheme-theoretically. Recall that X is defined by the coefficients of the characteristic polynomial of a generic 3 × 3 matrix M.

i16 : X = ideal substitute(
              contract(matrix{{t^2,t,1}}, det(t-M)),
              {t => 0_S})
o16 = ideal (- a - e - i, - b*d + a*e - c*g - f*h + a*i + e*i, c*e*g - · · ·
o16 : Ideal of S

    i17 : closureOfOrbit == X
    o17 = true
    i18 : clearAll

This completes our solution. ⊓ ⊔

More generally, Kostant shows that the set of all nilpotent elements in a complex semisimple Lie algebra form an irreducible variety. We refer the reader to Chriss and Ginzburg [1] for a proof of this result (Corollary 3.2.8) and a discussion of its applications in representation theory.

3 Singular Points

In our third question, we study the singular locus of a family of elliptic curves.

Problem. Consider a general form of degree 3 in ℚ[x, y, z]:

F = ax^{3} + bx^{2}y + cx^{2}z + dxy^{2} + exyz + fxz^{2} + gy^{3} + hy^{2}z + iyz^{2} + jz^{3} .

Give necessary and sufficient conditions in terms of a, …, j for the cubic curve Proj (ℚ[x, y, z]/⟨F ⟩) to have a singular point.

Solution. The singular locus of F is defined by a polynomial of degree 12 in the 10 variables a, …, j. We calculate this polynomial in two different ways.

Our first method is an elementary but time consuming elimination. Carrying it out in Macaulay 2, we have

    i19 : S = QQ[x, y, z, a..j, MonomialOrder => Eliminate 2];
    i20 : F = a*x^3+b*x^2*y+c*x^2*z+d*x*y^2+e*x*y*z+f*x*z^2+g*y^3+h*y^2*z+
                       i*y*z^2+j*z^3;
    i21 : partials = submatrix(jacobian matrix{{F}}, {0..2}, {0})
    o21 = {1} | 3x2a+2xyb+y2d+2xzc+yze+z2f |
          {1} | x2b+2xyd+3y2g+xze+2yzh+z2i |
          {1} | x2c+xye+y2h+2xzf+2yzi+3z2j |
                  3       1
    o21 : Matrix S  <--- S
    i22 : singularities = ideal(partials) + ideal(F);
    o22 : Ideal of S
    i23 : elimDiscr = time ideal selectInSubring(1,gens gb singularities);
         -- used 64.27 seconds
    o23 : Ideal of S
    i24 : elimDiscr = substitute(elimDiscr, {z => 1});
    o24 : Ideal of S

On the other hand, there is also an elegant and more useful determinantal formula for this discriminant; it is a specialization of the formula (2.8) in section 3.2 of Cox, Little and O‘Shea [3]. To apply this determinantal formula, we first create the coefficient matrix A of the partial derivatives of F.

i25 : A = contract(matrix{{x^2,x*y,y^2,x*z,y*z,z^2}},
              diff(transpose matrix{{x,y,z}},F))
o25 = {1} | 3a 2b d  2c e  f  |
      {1} | b  2d 3g e  2h i  |
      {1} | c  e  h  2f 2i 3j |
              3       6
o25 : Matrix S  <--- S

We also construct the coefficient matrix B of the partial derivatives of the Hessian of F.

i26 : hess = det submatrix(jacobian ideal partials, {0..2}, {0..2});
i27 : B = contract(matrix{{x^2,x*y,y^2,x*z,y*z,z^2}},
              diff(transpose matrix{{x,y,z}},hess))
o27 = {1} | -24c2d+24bce-18ae2-24b2f+72adf               4be2-16bdf-48 · · ·
      {1} | 2be2-8bdf-24c2g+72afg+16bch-24aeh-8b2i+24adi 4de2-16d2f-48 · · ·
      {1} | 2ce2-8cdf-8c2h+24afh+16bci-24aei-24b2j+72adj 2e3-8def-24cf · · ·
              3       6
o27 : Matrix S  <--- S

To obtain the discriminant, we combine these two matrices and take the determinant.

i28 : detDiscr = ideal det (A || B);
o28 : Ideal of S

Finally, we check that our two discriminants are equal

i29 : detDiscr == elimDiscr
o29 = true

and examine the generator.

i30 : detDiscr_0
            2   4 3 2             5 3 2           6 3 2          2 2 2 · · ·
o30 = 13824c d*e f g  - 13824b*c*e f g  + 13824a*e f g  - 110592c d e · · ·
o30 : S
i31 : numgens detDiscr
o31 = 1
i32 : # terms detDiscr_0
o32 = 2040
i33 : clearAll

Hence, the singular locus is given by a single polynomial of degree 12 with 2040 terms. ⊓ ⊔

For a further discussion of singularities and discriminants see Section V.3 in Eisenbud and Harris [5]. For information on resultants and discriminants see Chapter 2 in Cox, Little and O‘Shea [3].

4 Fields of Definition

Schemes over non-algebraically closed fields arise in number theory. Our fourth problem looks at one technique for working with number fields in Macaulay 2.

Problem (Exercise II-6 in [5]). An inclusion of fields K ↪ L induces a map 𝔸_{L}^{n} → 𝔸_{K}^{n}. Find the images in 𝔸_{ℚ}^{2} of the following points of 𝔸2 ; \overline{ℚ} under this map.

(1) ⟨x − \sqrt{2}, y − \sqrt{2}⟩;

(2) ⟨x − \sqrt{2}, y − \sqrt{3}⟩;

(3) ⟨x − ζ, y − ζ^{−1}⟩ where ζ is a 5-th root of unity ;

(4) ⟨\sqrt{2}x − \sqrt{3}y⟩;

(5) ⟨\sqrt{2}x − \sqrt{3}y − 1⟩.

Solution. The images can be determined by using the following three step algorithm: (1) replace the coefficients not contained in K with indeterminates,

(2) add the minimal polynomials of these coefficients to the given ideal in 𝔸_{L}^{2}, and (3) eliminate the new indeterminates. Here are the five examples:

    i34 : S = QQ[a,b,x,y, MonomialOrder => Eliminate 2];
    i35 : I1 = ideal(x-a, y-a, a^2-2);
    o35 : Ideal of S
    i36 : ideal selectInSubring(1, gens gb I1)
                         2
    o36 = ideal (x - y, y  - 2)
    o36 : Ideal of S
    i37 : I2 = ideal(x-a, y-b, a^2-2, b^2-3);
    o37 : Ideal of S
    i38 : ideal selectInSubring(1, gens gb I2)
                  2       2
    o38 = ideal (y  - 3, x  - 2)
    o38 : Ideal of S
    i39 : I3 = ideal(x-a, y-a^4, a^4+a^3+a^2+a+1);
    o39 : Ideal of S

    i40 : ideal selectInSubring(1, gens gb I3)
                           2    2               3    2
    o40 = ideal (x*y - 1, x  + y  + x + y + 1, y  + y  + x + y + 1)
    o40 : Ideal of S
    i41 : I4 = ideal(a*x+b*y, a^2-2, b^2-3);
    o41 : Ideal of S
    i42 : ideal selectInSubring(1, gens gb I4)
                 2   3  2
    o42 = ideal(x  - -*y )
                     2
    o42 : Ideal of S
    i43 : I5 = ideal(a*x+b*y-1, a^2-2, b^2-3);
    o43 : Ideal of S
    i44 : ideal selectInSubring(1, gens gb I5)
                 4     2 2   9  4    2   3  2   1
    o44 = ideal(x  - 3x y  + -*y  - x  - -*y  + -)
                             4           2      4
    o44 : Ideal of S
    i45 : clearAll

⊓ ⊔

It is worth noting that the points in 𝔸_{ℚ}^{n} correspond to orbits of the action of Gal(\overline{ℚ}/ℚ) on the points of 𝔸n ; \overline{ℚ}. For more examples and information, see section II.2 in Eisenbud and Harris [5].

5 Multiplicity

The multiplicity of a zero-dimensional scheme X at a point p ∈ X is defined to be the length of the local ring O_{X,p}. Unfortunately, we cannot work directly in the local ring in Macaulay 2. What we can do, however, is to compute the multiplicity by computing the degree of the component of X supported at p; see page 66 in Eisenbud and Harris [5].

Problem. What is the multiplicity of the origin as a zero of the polynomial equations x^{5} + y^{3} + z^{3} = x^{3} + y^{5} + z^{3} = x^{3} + y^{3} + z^{5} = 0?

Solution. If I is the ideal generated by x^{5}+y^{3}+z^{3}, x^{3}+y^{5}+z^{3} and x^{3}+y^{3}+z^{5} in ℚ[x, y, z], then the multiplicity of the origin is

dim_{ℚ} \frac{ℚ[x, y, z]_{⟨x,y,z⟩}}{Iℚ[x, y, z]_{⟨x,y,z⟩}} .

It follows that the multiplicity is the vector space dimension of the ring ℚ[x, y, z]/φ^{−1}(Iℚ[x, y, z]_{⟨x,y,z⟩}) where φ: ℚ[x, y, z] → ℚ[x, y, z]_{⟨x,y,z⟩} is the natural map. Moreover, we can express this using ideal quotients:

φ^{−1}(Iℚ[x, y, z]_{⟨x,y,z⟩}) = (I : (I : ⟨x, y, z⟩^{∞})) .

Carrying out this calculation in Macaulay 2, we obtain:

    i46 : S = QQ[x, y, z];
    i47 : I = ideal(x^5+y^3+z^3, x^3+y^5+z^3, x^3+y^3+z^5);
    o47 : Ideal of S
    i48 : multiplicity = degree(I : saturate(I))
    o48 = 27
    i49 : clearAll

Thus, we conclude that the multiplicity is 27. ⊓ ⊔

There are algorithms (not yet implemented in Macaulay 2) for working directly in the local ring ℚ[x, y, z]_{⟨x,y,z⟩}. We refer the interested reader to Chapter 4 in Cox, Little and O‘Shea [3].

6 Flat Families

Non-reduced schemes arise naturally as flat limits of a family of reduced schemes. Our next problem illustrates how a family of skew lines in ℙ^{3} gives rise to a double line with an embedded point.

Problem (Exercise III-68 in [5]). Let L and M be the lines in ℙ_{k[t]}^{3} given by x = y = 0 and x − tz = y + t^{2}w = 0 respectively. Show that the flat limit as t → 0 of the union L ∪ M is the double line x^{2} = y = 0 with an embedded point of degree 1 located at the point (0 : 0 : 0 : 1).

Solution. We first find the flat limit by saturating the intersection ideal and setting t = 0.

    i50 : PP3 = QQ[t, x, y, z, w];
    i51 : L = ideal(x, y);
    o51 : Ideal of PP3
    i52 : M = ideal(x-t*z, y+t^2*w);
    o52 : Ideal of PP3
    i53 : X = intersect(L, M);
    o53 : Ideal of PP3

    i54 : Xzero = trim substitute(saturate(X, t), {t => 0})
                       2        2
    o54 = ideal (y*z, y , x*y, x )
    o54 : Ideal of PP3

Secondly, we verify that this is the union of a double line and an embedded point of degree 1.

    i55 : Xzero == intersect(ideal(x^2, y), ideal(x, y^2, z))
    o55 = true
    i56 : degree(ideal(x^2, y ) / ideal(x, y^2, z))
    o56 = 1
    i57 : clearAll

⊓ ⊔

Section III.3.4 in Eisenbud and Harris [5] contains several other interesting limits of various flat families.

7 Bézout’s Theorem

Bézout’s Theorem — Theorem III-78 in Eisenbud and Harris [5] — may fail without the Cohen-Macaulay hypothesis. Our seventh problem is to demonstrate this.

Problem (Exercise III-81 in [5]). Find irreducible closed subvarieties X and Y in ℙ^{4} such that

codim(X ∩ Y) = codim(X) + codim(Y)
deg(X ∩ Y) > deg(X) · deg(Y) .

Solution. We show that the assertion holds when X is the cone over the nonsingular rational quartic curve in ℙ^{3} and Y is a two-plane passing through the vertex of the cone. First, recall that the rational quartic curve is given by the 2 × 2 minors of the matrix [ \begin{matrix}a & b^{2} & bd & c \\ b & ac & c^{2} & d \end{matrix} ]; see Exercise 18.8 in Eisenbud [4]. Thus, we have

    i58 : S = QQ[a, b, c, d, e];
    i59 : IX = trim minors(2, matrix{{a, b^2, b*d, c},{b, a*c, c^2, d}})
                             3      2     2    2    3    2
    o59 = ideal (b*c - a*d, c  - b*d , a*c  - b d, b  - a c)
    o59 : Ideal of S
    i60 : IY = ideal(a, d);
    o60 : Ideal of S

    i61 : codim IX + codim IY == codim (IX + IY)
    o61 = true
    i62 : (degree IX) * (degree IY)
    o62 = 4
    i63 : degree (IX + IY)
    o63 = 5

which establishes the assertion. ⊓ ⊔

To understand how this example works, it is enlightening to express Y as the intersection of two hyperplanes; one given by a = 0 and the other given by d = 0. Intersecting X with the first hyperplane yields

    i64 : J = ideal mingens (IX + ideal(a))
                          3      2   2    3
    o64 = ideal (a, b*c, c  - b*d , b d, b )
    o64 : Ideal of S

However, this first intersection has an embedded point;

    i65 : J == intersect(ideal(a, b*c, b^2, c^3-b*d^2),
               ideal(a, d, b*c, c^3, b^3)) -- embedded point
    o65 = true
    i66 : clearAll

The second hyperplane passes through this embedded point which explains the extra intersection.

8 Constructing Blow-ups

The blow-up of a scheme X along a subscheme Y can be constructed from the Rees algebra associated to the ideal sheaf of Y in X; see Theorem IV-22 in Eisenbud and Harris [5]. Gröbner basis techniques allow one to express the Rees algebra in terms of generators and relations. We illustrate this method in the next solution.

Problem (Exercises IV-43 & IV-44 in [5]). Find the blow-up X of the affine plane 𝔸^{2} = Spec (ℚ[x, y]) along the subscheme defined by ⟨x^{3}, xy, y^{2}⟩. Show that X is nonsingular and its fiber over the origin is the union of two copies of ℙ^{1} meeting at a point.

Solution. We first provide a general function which returns the ideal of relations for the Rees algebra.

    i67 : blowUpIdeal = (I) -> (
               r := numgens I;
               S := ring I;
               n := numgens S;
               K := coefficientRing S;
               tR := K[t, gens S, vars(0..r-1),
                         MonomialOrder => Eliminate 1];
               f := map(tR, S, submatrix(vars tR, {1..n}));
               F := f(gens I);
               J := ideal apply(1..r, j -> (gens tR)_(n+j)-t*F_(0,(j-1)));
               L := ideal selectInSubring(1, gens gb J);
               R := K[gens S, vars(0..r-1)];
               g := map(R, tR, 0 | vars R);
               trim g(L));

Now, applying the function to our specific case yields:

    i68 : S = QQ[x, y];
    i69 : I = ideal(x^3, x*y, y^2);
    o69 : Ideal of S
    i70 : J = blowUpIdeal(I)
                               2         2          3     2
    o70 = ideal (y*b - x*c, x*b  - a*c, x b - y*a, x c - y a)
    o70 : Ideal of QQ [x, y, a, b, c]

Therefore, the blow-up of the affine plane along the given subscheme is

X = Proj (\frac{(ℚ[x, y])[a, b, c]}{⟨yb − xc, xb^{2} − ac, x^{2}b − ya, x^{3}c − y^{2}a⟩}) .

Using Macaulay 2, we can also verify that the scheme X is nonsingular;

    i71 : J + ideal jacobian J == ideal gens ring J
    o71 = true
    i72 : clearAll

Since we have

\frac{(ℚ[x, y])[a, b, c]}{⟨yb − xc, xb^{2} − ac, x^{2}b − ya, x^{3}c − y^{2}a⟩} ⊗ \frac{ℚ[x, y]}{⟨x, y⟩} ≅ \frac{ℚ[a, b, c]}{⟨ac⟩} ,

the fiber over the origin ⟨x, y⟩ in 𝔸^{2} is clearly a union of two copies of ℙ^{1} meeting at one point. In particular, the exceptional fiber is not a projective space. ⊓ ⊔

Many other interesting blow-ups can be found in section II.2 in Eisenbud and Harris [5].

9 A Classic Blow-up

We consider the blow-up of the projective plane ℙ^{2} at a point.

12  G. G. Smith and B. Sturmfels

Problem. Show that the following varieties are isomorphic.

(a) the image of the rational map from ℙ^{2} to ℙ^{4} given by

(r : s : t) ↦ (r^{2} : s^{2} : rs : rt : st) ;

(b) the blow-up of the plane ℙ^{2} at the point (0 : 0 : 1);

(c) the determinantal variety defined by the 2×2 minors of the matrix [ \begin{matrix}a & c & d \\ b & d & e \end{matrix} ] where ℙ^{4} = Proj (k[a, b, c, d, e]).

This surface is called the cubic scroll in ℙ^{4}.

Solution. We find the ideal in part (a) by elimination theory.

i73 : PP4 = QQ[a..e];
i74 : S = QQ[r..t, A..E, MonomialOrder => Eliminate 3];
i75 : I = ideal(A - r^2, B - s^2, C - r*s, D - r*t, E - s*t);
o75 : Ideal of S
i76 : phi = map(PP4, S, matrix{{0_PP4, 0_PP4, 0_PP4}} | vars PP4)
o76 = map(PP4,S,{0, 0, 0, a, b, c, d, e})
o76 : RingMap PP4 <--- S
i77 : surfaceA = phi ideal selectInSubring(1, gens gb I)
                                           2
o77 = ideal (c*d - a*e, b*d - c*e, a*b - c )
o77 : Ideal of PP4

Next, we determine the surface in part (b). We construct the ideal defining the blow-up of ℙ^{2}

i78 : R = QQ[t, x, y, z, u, v, MonomialOrder => Eliminate 1];
i79 : blowUpIdeal = ideal selectInSubring(1, gens gb ideal(u-t*x,
           v-t*y))
o79 = ideal(y*u - x*v)
o79 : Ideal of R

and embed it in ℙ^{2} × ℙ^{1}.

i80 : PP2xPP1 = QQ[x, y, z, u, v];
i81 : embed = map(PP2xPP1, R, 0 | vars PP2xPP1);
o81 : RingMap PP2xPP1 <--- R
i82 : blowUp = PP2xPP1 / embed(blowUpIdeal);

We then map this surface into ℙ^{5} using the Segre embedding.

i83 : PP5 = QQ[A .. F];

i84 : segre = map(blowUp, PP5, matrix{{x*u,y*u,z*u,x*v,y*v,z*v}});
o84 : RingMap blowUp <--- PP5
i85 : ker segre
                                2
o85 = ideal (B - D, C*E - D*F, D  - A*E, C*D - A*F)
o85 : Ideal of PP5

Note that the image under the Segre map lies on a hyperplane in ℙ^{5}. To get the desired surface in ℙ^{4}, we project

i86 : projection = map(PP4, PP5, matrix{{a, c, d, c, b, e}})
o86 = map(PP4,PP5,{a, c, d, c, b, e})
o86 : RingMap PP4 <--- PP5
i87 : surfaceB = trim projection ker segre
                                           2
o87 = ideal (c*d - a*e, b*d - c*e, a*b - c )
o87 : Ideal of PP4

Finally, we compute the surface in part (c).

i88 : determinantal = minors(2, matrix{{a, c, d}, {b, d, e}})
                                           2
o88 = ideal (- b*c + a*d, - b*d + a*e, - d  + c*e)
o88 : Ideal of PP4
i89 : sigma = map( PP4, PP4, matrix{{d, e, a, c, b}});
o89 : RingMap PP4 <--- PP4
i90 : surfaceC = sigma determinantal
                                           2
o90 = ideal (c*d - a*e, b*d - c*e, a*b - c )
o90 : Ideal of PP4

By incorporating a permutation of the variables into definition of surfaceC, we obtain the desired isomorphisms

i91 : surfaceA == surfaceB
o91 = true
i92 : surfaceB == surfaceC
o92 = true
i93 : clearAll

which completes the solution. ⊓ ⊔

For more information of the geometry of rational normal scrolls, see Lecture 8 in Harris [6].

10 Fano Schemes

Our final example concerns the family of Fano schemes associated to a flat family of quadrics. Recall that the k-th Fano scheme F_{k}(X) of a scheme X ⊆ ℙ^{n} is the subscheme of the Grassmannian parametrizing k-planes contained in X.

Problem (Exercise IV-69 in [5]). Consider the one-parameter family of quadrics tending to a double plane with equation

Q = V (tx^{2} + ty^{2} + tz^{2} + w^{2}) ⊆ ℙ_{ℚ[t]}^{3} = Proj (ℚ[t][x, y, z, w]) .

What is the flat limit of the Fano schemes F_{1}(Q_{t})?

Solution. We first compute the ideal defining F_{1}(Q_{t}), the scheme parametrizing lines in Q.

    i94 : PP3 = QQ[t, x, y, z, w];
    i95 : Q = ideal( t*x^2+t*y^2+t*z^2+w^2 );
    o95 : Ideal of PP3

To parametrize a line in our projective space, we introduce indeterminates u, v and A, …, H.

    i96 : R = QQ[t, u, v, A .. H];

We then make a map phi from PP3 to R sending the variables to the coordinates of the general point on a line.

    i97 : phi = map(R, PP3, matrix{{t}} |
                  u*matrix{{A, B, C, D}} + v*matrix{{E, F, G, H}});
    o97 : RingMap R <--- PP3
    i98 : imageFamily = phi Q;
    o98 : Ideal of R

For a line to belong to Q, the imageFamily must vanish identically. In other words, F_{1}(Q) is defined by the coefficients of the generators of imageFamily.

    i99 : coeffOfFamily = contract(matrix{{u^2,u*v,v^2}}, gens imageFamily)
    o99 = | tA2+tB2+tC2+D2 2tAE+2tBF+2tCG+2DH tE2+tF2+tG2+H2 |
                  1       3
    o99 : Matrix R  <--- R

Since we don’t need the variables u and v, we get rid of them.

    i100 : S = QQ[t, A..H];
    i101 : coeffOfFamily = substitute(coeffOfFamily, S);
                   1       3
    o101 : Matrix S  <--- S
    i102 : Sbar = S / (ideal coeffOfFamily);

Next, we move to the Grassmannian 𝔾(1, 3) ⊂ ℙ^{5}. Recall the homogeneous coordinates on ℙ^{5} correspond to the 2×2 minors of a 2×4 matrix. We obtain these minors using the exteriorPower function in Macaulay 2.

i103 : psi = matrix{{t}} | exteriorPower(2,
                   matrix{{A, B, C, D}, {E, F, G, H}})
o103 = | t -BE+AF -CE+AG -CF+BG -DE+AH -DF+BH -DG+CH |
                  1          7
o103 : Matrix Sbar  <--- Sbar
i104 : PP5 = QQ[t, a..f];
i105 : fanoOfFamily = trim ker map(Sbar, PP5, psi);
o105 : Ideal of PP5

Now, to answer the question, we determine the limit as t tends to 0.

i106 : zeroFibre = trim substitute(saturate(fanoOfFamily, t), {t=>0})
                    2   2                   2  · · ·
o106 = ideal (e*f, d*f, e , f , d*e, a*e + b*f, d , c*d - b*e + a*f, b · · ·
o106 : Ideal of PP5

Let’s transpose the matrix of generators so all of its elements are visible on the printed page.

i107 : transpose gens zeroFibre
o107 = {-2} | ef       |
       {-2} | df       |
       {-2} | e2       |
       {-2} | f2       |
       {-2} | de       |
       {-2} | ae+bf    |
       {-2} | d2       |
       {-2} | cd-be+af |
       {-2} | bd+ce    |
       {-2} | ad-cf    |
       {-2} | a2+b2+c2 |
                 11         1
o107 : Matrix PP5   <--- PP5

We see that F_{1}(Q_{0}) is supported on the plane conic ⟨d, e, f, a^{2} + b^{2} + c^{2}⟩. However, F_{1}(Q_{0}) is not reduced; it has multiplicity two. On the other hand, the generic fiber is

i108 : oneFibre = trim substitute(saturate(fanoOfFamily, t), {t => 1})
                     2    2    2  · · ·
o108 = ideal (a*e + b*f, d  + e  + f , c*d - b*e + a*f, b*d + c*e, a*d · · ·
o108 : Ideal of PP5
i109 : oneFibre == intersect(ideal(c-d, b+e, a-f, d^2+e^2+f^2),
            ideal(c+d, b-e, a+f, d^2+e^2+f^2))
o109 = true

Hence, for t ≠ 0, F_{1}(Q_{t}) is the union of two conics lying in complementary planes and F_{1}(Q_{0}) is the double conic obtained when the two conics move together. ⊓ ⊔

References

1. Neil Chriss and Victor Ginzburg: Representation theory and complex geometry. Birkhäuser Boston Inc., Boston, MA, 1997.

2. David Cox, John Little, and Donal O’Shea: Ideals, varieties, and algorithms. Springer-Verlag, New York, second edition, 1997. An introduction to computational algebraic geometry and commutative algebra.

3. David Cox, John Little, and Donal O’Shea: Using algebraic geometry. Springer-Verlag, New York, 1998.

4. David Eisenbud: Commutative algebra with a view toward algebraic geometry. Springer-Verlag, New York, 1995.

5. David Eisenbud and Joe Harris: The geometry of schemes. Springer-Verlag, New York, 2000.

6. Joe Harris: Algebraic geometry, A first course. Springer-Verlag, New York, 1995.

Index

Bézout’s Theorem 9 blow-up 10, 11

classical adjoint 3 Cohen-Macaulay 9 cubic scroll 12

determinantal variety

12 discriminant 5

elimination theory 3, 12 elliptic curve 4 embedded point 8, 10

Fano scheme 14 flat limit 8, 14

Grassmannian 15

hessian 5

Lie algebra 4

multiplicity 7, 15

nilpotent orbits 2

one-parameter family rational parameterization

2 rational quartic curve 9 Rees algebra 10

saturation 1, 8 scheme

– affine 1, 10

– arithmetic 1

– irreducible 2

– non-reduced 8, 15

– over a number field 6 – reduced 8 Segre embedding 12 singular locus 4, 11